Skip to content

環

module ring where

open import abelian-group
open import apartness-relation
open import group
open import monoid
open import sigma-type

環を定義する。環は加法を表すAbel群Addと乗法を表すモノイドMulから成り、乗法が加法に分配するものである。

record RingStr (S : ApartedSet) : Set where
  open ApartedSet S

  field
    Add : AbelianGroupStr S
    Mul : MonoidStr S

  module Add = AbelianGroupStr Add
  module Mul = MonoidStr Mul

  open AbelianGroupStr Add public
    using (zero; _+_; -_)

  open MonoidStr Mul public
    using (_·_)
    renaming (empty to one)

  field
    ·-distr-+ₗ : ∀ {x y z} → x · (y + z) ≈ (x · y) + (x · z)
    ·-distr-+ᵣ : ∀ {x y z} → (x + y) · z ≈ (x · z) + (y · z)
Ring : Set₁
Ring = Σ ApartedSet RingStr

非自明な環とは、zeroとoneが異なるような環である。

isNonTrivialRingStr : (S : ApartedSet) → RingStr S → Set
isNonTrivialRingStr S R = zero # one
  where
    open ApartedSet S
    open RingStr R

isNonTrivialRing : Ring → Set
isNonTrivialRing (S , R) = isNonTrivialRingStr S R
module RingProperties (R : Ring) where
  open ApartedSet (R .fst)
  open RingStr (R .snd)
  open GroupProperties (R .fst , Add .AbelianGroupStr.group-str)

  private
    helper : ∀ x → zero · x + zero · x ≈ zero · x
    helper x = trans-≈ a (Mul.·-pres-∼ₗ x .fst Add.lunit)
      where
        a : zero · x + zero · x ≈ (zero + zero) · x
        a = sym-≈ (·-distr-+ᵣ {z = x})

  zero-absorb-everything : ∀ x → zero · x ≈ zero
  zero-absorb-everything x =
    trans-≈ (move-to-right .fst (helper x)) (Add.rinv _)